Mostrar o Endereço de IP do Utilizador numa Célula (VBA)

Resumo

Todos os computadores são identificados por um número e um nome, são eles o número de IP e o HOST NAME. Desta forma, quando estamos conectados em rede temos uma identificação única para o nosso computador.

Macro para identificar o IP e o HOST

Podemos usar o VBA no Excel para criar Funções Personalizadas que nos irão devolver o IP e o HOST NAME da máquina em que estamos a trabalhar.

1. A forma mais fácil é iniciar a gravação de uma macro e interromper a gravação (aprender mais sobre como criar Macros aqui).

2. Depois de criar a Macro basta apenas substituir o código da Macro criada pelo código abaixo.

Option Explicit
Public Const MAX_WSADescription As Long = 256
Public Const MAX_WSASYSStatus As Long = 128
Public Const ERROR_SUCCESS As Long = 0
Public Const WS_VERSION_REQD As Long = &H101
Public Const WS_VERSION_MAJOR As Long = WS_VERSION_REQD \ &H100 And &HFF&
Public Const WS_VERSION_MINOR As Long = WS_VERSION_REQD And &HFF&
Public Const MIN_SOCKETS_REQD As Long = 1
Public Const SOCKET_ERROR As Long = -1
Public Type HOSTENT
hName As Long
hAliases As Long
hAddrType As Integer
hLen As Integer
hAddrList As Long
End Type
Public Type WSADATA
wVersion As Integer
wHighVersion As Integer
szDescription(0 To MAX_WSADescription) As Byte
szSystemStatus(0 To MAX_WSASYSStatus) As Byte
wMaxSockets As Integer
wMaxUDPDG As Integer
dwVendorInfo As Long
End Type
Public Declare Function WSAGetLastError Lib "wsock32" () As Long
Public Declare Function WSAStartup Lib "wsock32" (ByVal wVersionRequired As Long, lpWSADATA As WSADATA) As Long
Public Declare Function WSACleanup Lib "wsock32" () As Long
Public Declare Function gethostname Lib "wsock32" (ByVal szHost As String, ByVal dwHostLen As Long) As Long
Public Declare Function gethostbyname Lib "wsock32" (ByVal szHost As String) As Long
Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (hpvDest As Any, ByVal hpvSource As Long, ByVal cbCopy As Long)
Public Function GetIPAddress() As String
Dim sHostName As String * 256
Dim lpHost As Long
Dim HOST As HOSTENT
Dim dwIPAddr As Long
Dim tmpIPAddr() As Byte
Dim i As Integer
Dim sIPAddr As String
If Not SocketsInitialize() Then
    GetIPAddress = ""
    Exit Function
End If
If gethostname(sHostName, 256) = SOCKET_ERROR Then
   GetIPAddress = ""
   MsgBox "Ocorreu um erro de Socket : " & Str$(WSAGetLastError()) & " , não é possivel obter o Host Name."
   SocketsCleanup
   Exit Function
End If
sHostName = Trim$(sHostName)
lpHost = gethostbyname(sHostName)
If lpHost = 0 Then
  GetIPAddress = ""
  MsgBox "Windows Sockets não está a responder. " & vbCrLf & "Não é possivel obter o Host Name"
  SocketsCleanup
  Exit Function
End If
CopyMemory HOST, lpHost, Len(HOST)
CopyMemory dwIPAddr, HOST.hAddrList, 4
ReDim tmpIPAddr(1 To HOST.hLen)
CopyMemory tmpIPAddr(1), dwIPAddr, HOST.hLen
For i = 1 To HOST.hLen
  sIPAddr = sIPAddr & tmpIPAddr(i) & "."
Next
GetIPAddress = Mid$(sIPAddr, 1, Len(sIPAddr) - 1)
SocketsCleanup
End Function
Public Function GetIPHostName() As String
Dim sHostName As String * 256
If Not SocketsInitialize() Then
  GetIPHostName = ""
  Exit Function
End If
If gethostname(sHostName, 256) = SOCKET_ERROR Then
  GetIPHostName = ""
  MsgBox "Erro Windows Sockets " & Str$(WSAGetLastError()) & " não é possivel obter o Host Name."
  SocketsCleanup
  Exit Function
End If
GetIPHostName = Left$(sHostName, InStr(sHostName, Chr(0)) - 1)
SocketsCleanup
End Function
Public Function HiByte(ByVal wParam As Integer) As Byte
HiByte = (wParam And &HFF00&) \ (&H100)
End Function
Public Function LoByte(ByVal wParam As Integer) As Byte
  LoByte = wParam And &HFF&
End Function
Public Sub SocketsCleanup()
If WSACleanup() <> ERROR_SUCCESS Then
  MsgBox " Erro de Socket."
End If
End Sub
Public Function SocketsInitialize() As Boolean
Dim WSAD As WSADATA
Dim sLoByte As String
Dim sHiByte As String
If WSAStartup(WS_VERSION_REQD, WSAD) <> ERROR_SUCCESS Then
  MsgBox "Windows Socket 32-bit não está a responder."
  SocketsInitialize = False
  Exit Function
End If
If WSAD.wMaxSockets < MIN_SOCKETS_REQD Then
MsgBox " Esta aplicação necessita de um mínimo de " & _
CStr(MIN_SOCKETS_REQD) & " sockets suportados."
SocketsInitialize = False
Exit Function
End If
If LoByte(WSAD.wVersion) < WS_VERSION_MAJOR Or (LoByte(WSAD.wVersion) = WS_VERSION_MAJOR And HiByte(WSAD.wVersion) < WS_VERSION_MINOR) Then
  sHiByte = CStr(HiByte(WSAD.wVersion))
  sLoByte = CStr(LoByte(WSAD.wVersion))
  MsgBox "A versão Sockets " & sLoByte & "." & sHiByte & " não é suportada por Windows Sockets 32-bit."
  SocketsInitialize = False
Exit Function
End If
SocketsInitialize = True
End Function

3. De seguida, gravamos o ficheiro como Livro com Permissões para Macros (com a extensão XLSM).

4. Depois deste processo podemos usar as Funções Personalizadas que acabamos de criar para inserir numa célula o IP:

=GetIPAddress()

E o HOST NAME do computador em que o ficheiro está aberto:

=GetIPHostName()

Descargas

Descarrega aqui o ficheiro com os exemplos para mostrar o endereço de IP do utilizador