Função SUMIF (Soma.se) no Excel

Resumo

SOMA.SE (Sumif) é uma função do Excel que soma células que correspondem a uma condição única num determinado intervalo de dados. Esta condição pode ser utilizada com datas, números ou texto suportando operadores lógicos >, <, <>, = e wildcards *, ? para pesquisa parcial.

Sintaxe

=SOMA.SE (intervalo_de_procura; critério; intervalo_de_soma)

Argumentos

intervalo_de_procura // o intervalo de células em que queremos procurar o critério
critério // o critério que define que células contamos
intervalo_de_soma // o intervalo de células em que queremos realizar a soma [OPCIONAL: só é necessário se o intervalo_de_soma for diferente do intervalo_de_procura]

1. SOMA.SE (Sumif) com a soma no intervalo de procura [Célula J5]

=SOMA.SE($G$4:$G$19;"<50")

=SOMA.SE($G$4:$G$19; // o intervalo de células que queremos contar
"<50" // o critério que queremos procurar, neste caso, vendas maiores ou iguais a 100

O intervalo_de_procura e o intervalo_de_soma são os mesmos.

2. SOMA.SE (Sumif) com o critério numa célula adjacente [Célula J6]

=SOMA.SE($G$4:$G$19;">"&DIREITA(I6;4);$G$4:$G$19)

=SOMA.SE($G$4:$G$19; // o intervalo de células em que queremos procurar o critério
">"&DIREITA(I6;4) // o critério que queremos procurar, neste caso, maior que os últimos 4 dígitos à direita da célula adjacente: >100€
$G$4:$G$19) // o intervalo de células em que queremos realizar a soma

3. SOMA.SE (Sumif) com critério introduzido na fórmula [Célula J7]

=SOMA.SE($F$4:$F$19;"M";$G$4:$G$19)

=SOMA.SE($F$4:$F$19; // o intervalo de células em que queremos procurar o critério
"M" // o critério que queremos procurar, neste caso, "M" que corresponde a Sexo Masculino
$G$4:$G$19) // o intervalo de células em que queremos realizar a soma

4. SOMA.SE (Sumif) com um critério diferente de determinado valor [Célula J8]

=SOMA.SE($D$4:$D$19;"<>Portugal";$G$4:$G$19)

=SOMA.SE($D$4:$D$19; // o intervalo de células em que queremos procurar o critério
"<>Portugal" // o critério que queremos procurar, neste caso, valores diferentes de "Portugal"
$G$4:$G$19) // o intervalo de células em que queremos realizar a soma

5. SOMA.SE (Sumif) com o critério igual ao valor de uma célula adjacente [Célula J9]

=SOMA.SE($D$4:$D$19;I9;$G$4:$G$19)

=SOMA.SE($D$4:$D$19; // o intervalo de células em que queremos procurar o critério
I9; // o critério que queremos procurar, neste caso, o valor na Célula I9 que corresponde a "Portugal"
$G$4:$G$19) // o intervalo de células em que queremos realizar a soma

6. SOMA.SE (Sumif) usando um wildcard para procurar células que contenham parte desse valor [Célula J10]

=SOMA.SE($C$4:$C$19;"*ma*";$G$4:$G$19)

=SOMA.SE($G$4:$G$19; // o intervalo de células em que queremos procurar o critério
"*ma*"; // o critério que queremos procurar, neste caso, palavras que contenham "ma"
$G$4:$G$19) // o intervalo de células em que queremos realizar a soma

A Função SOMA.SE (Sumif) não é Case-Sensitive, ou seja, podemos escrever "MA", "Ma", "mA", "ma", e a soma devolvida será sempre a mesma.

7. SOMA.SE (Sumif) para contar Células Vazias [Célula J12 + J13]

=SOMA.SE($N$5:$N$10;"<>";$M$5:$M$10) // soma o intervalo das células correspondentes às células não vazias
=SOMA.SE($N$5:$N$10;"";$M$5:$M$10) // soma o intervalo das células correspondentes às células vazias

8. SOMA.SE (Sumif) com datas como critério de procura [Célula J17 + J18]

=SOMA.SE($L$5:$L$10;"<"&I17;$M$5:$M$10)

=SOMA.SE($L$5:$L$10; // o intervalo de células em que queremos procurar o critério
"<"&I17; // o critério que queremos procurar, neste caso, usando uma data de uma célula adjacente concatenada com um operador ("<")
$M$5:$M$10) // o intervalo de células em que queremos realizar a soma

=SOMA.SE($L$5:$L$10;"<"&DATA(2020;6;1);$M$5:$M$10)

=SOMA.SE($L$5:$L$10; // o intervalo de células em que queremos procurar o critério
"<"&DATA(2020;6;1); // o critério que queremos procurar, neste caso, usando a Função DATA (Date) concatenada com um operador ("<")
$M$5:$M$10) // o intervalo de células em que queremos realizar a soma

Para utilizações mais complexas com elementos da data, por exemplo todas as datas em determinado mês ou datas entre duas datas diferentes, recomenda-se a Função SOMA.SE.S (Sumifs) que permite utilizar mais do que um critério de procura.

Descargas

Descarrega aqui o ficheiro com os exemplos para usar a função SUMIF